Follow

Como exportar uma geometria deformada de uma análise estrutural no AIM?

Saudações. 

 

No artigo de hoje será mostrado como é o procedimento para exportar o CAD de um resultado de um estudo estrutural no AIM. 

A primeira coisa a ser feita é o setup de seu caso normalmente, com todas as etapas elementares: Trabalho do CAD, geração de malha, definição de carregamentos e condições de contorno. 

Na Aba Physics, em Solver Options clique em Add > User Commands.

Screen_Shot_09-12-17_at_08.18_AM.PNG

Na janela que aparecerá, acesse a Aba Post 1

Screen_Shot_09-12-17_at_08.20_AM.PNG

E aqui, nesta linha 1, cole o seguinte código:

finish
/prep7
save,tempdata,db
finish
/clear
/prep7
upgeom,1,,,file,rst
/prep7
et,1000,154
alls
nsel,s,ext
esel,s,ename,,181
esel,a,ename,,281
nsle,a
esel,all
type,1000
esurf
alls
esel,s,type,,1000
nsle,s
*get,nbe,elem,0,count
e0=elnext(0)
nkp=1
*do,i,1,nbe
nkpi=nkp-1
*do,j,1,8
n%j%=nelem(e0,j)
k,nkp,nx(n%j%),ny(n%j%),nz(n%j%)
nkp=nkp+1
*enddo
*if,n4,eq,n3,then
a,nkpi+1,nkpi+5,nkpi+6
a,nkpi+5,nkpi+2,nkpi+6
a,nkpi+6,nkpi+3,nkpi+8
a,nkpi+1,nkpi+6,nkpi+8
*else
a,nkpi+1,nkpi+5,nkpi+8
a,nkpi+5,nkpi+2,nkpi+6
a,nkpi+6,nkpi+3,nkpi+7
a,nkpi+7,nkpi+4,nkpi+8
a,nkpi+8,nkpi+5,nkpi+6
a,nkpi+6,nkpi+7,nkpi+8
*endif
e0=elnext(e0)
*enddo
allsel
nummrg,kpoi
cdopt,iges
cdwrite,solid,,,,geometriadeformada,iges
finish
/post1
resume,tempdata,db
alls

 

Screen_Shot_09-12-17_at_08.21_AM.PNG

Agora basta rodar o caso normalmente.

Screen_Shot_09-12-17_at_08.23_AM.PNG

Ao término do cálculo, salve seu estudo. A geometria deformada se encontra na pasta de trabalho do workbench. No meu caso, devo acessar: 

C:\Users\luiz\example_files\dp0\Study\AIM\physics

Nesta pasta, devo procurar pelo arquivo chamado geometriadeformada.igs e poderei abrir este arquivo em qualquer CAD de minha preferência. Se a escolha for pelo ANSYS SpaceClaim, que é a nossa principal ferramenta para tratamento de CAD e que é inclusa ao AIM, pode-se facilmente trabalhar este modelo deformado para que os sólidos sejam fechados e que quaisquer modificações de interesse sejam feitas. Pode-se também converter este arquivo para STL. 

Screen_Shot_09-12-17_at_08.29_AM.PNG

DICAS:

Este Script elaborado pela ESSS possibilita ao usuário que se exporte os corpos volumétricos e corpos de casca da análise. Na atual versão do AIM durante a elaboração deste script e artigo (R18.2) os elementos de viga ainda se encontram como BETA e não são contemplados para a exportação. 

 

O Script só funciona com elementos de segunda ordem (quadráticos) de malha, tanto para os corpos volumétricos quanto para os corpos de casca. Assim, assegure-se de gerar uma malha condizente. Para garantir que os elementos gerados serão de segunda ordem acesse

Mesh > Additional Settings > Midside Nodes > Kept

Screen_Shot_09-12-17_at_08.34_AM.PNG

 

Este código também funciona para o ANSYS Mechanical, que é outra ferramenta da ANSYS vendida separadamente. Se você é usuário do Mechanical, sinta-se à vontade para usar o código. Apenas certifique-se de criar o comando APDL no pós processamento e não no pré. 

 

Espero que seja útil. A equipe técnica da ESSS está à disposição. 

Atenciosamente,

Luiz Gustavo Franco Amaral

 

Was this article helpful?
0 out of 0 found this helpful
Have more questions? Submit a request

Comments


Powered by Zendesk